blob: e5ee6ec271555fc141eef265e456d0c04c14d473 (
plain) (
blame)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
|
(define-library (csc match)
(export match)
(import (scheme base))
(begin
; From https://cookbook.scheme.org/check-for-symbol-in-syntax-rules/
(define-syntax symbol??
(syntax-rules ()
((symbol?? (_ . _) _ kf) kf) ; It's a pair, not a symbol.
((symbol?? #(_ ...) _ kf) kf) ; It's a vector, not a symbol.
((symbol?? maybe-symbol kt kf)
(let-syntax
((test
(syntax-rules ()
((test maybe-symbol t _) t)
((test _ _ f) f))))
(test abracadabra kt kf)))))
(define-syntax matches?
(syntax-rules (_)
((matches? x _) #t)
((matches? x '())
(null? x))
((matches? x (pattern))
(and (= 1 (length x))
(matches? (car x) pattern)))
((matches? x (pattern1 . pattern2))
(and (pair? x)
(matches? (car x) pattern1)
(matches? (cdr x) pattern2)))
((matches? x lit)
(symbol?? lit
#t
(equal? x lit)))))
(define-syntax bind-pattern
(syntax-rules (_)
((bind-pattern x _ result1 result2 ...)
(begin result1 result2 ...))
((bind-pattern x '() result1 result2 ...)
(begin result1 result2 ...))
((bind-pattern x (pattern) result1 result2 ...)
(bind-pattern (car x) pattern result1 result2 ...))
((bind-pattern x (pattern1 . pattern2) result1 result2 ...)
(bind-pattern (car x) pattern1
(bind-pattern (cdr x) pattern2 result1 result2 ...)))
((bind-pattern x lit result1 result2 ...)
(symbol?? lit
(let ((lit x))
result1 result2 ...)
(begin result1 result2 ...)))))
(define-syntax match
(syntax-rules ()
((match x (pattern result1 result2 ...))
(if (matches? x pattern)
(bind-pattern x pattern result1 result2 ...)))
((match x (pattern result1 result2 ...) clause1 clause2 ...)
(if (matches? x pattern)
(bind-pattern x pattern result1 result2 ...)
(match x clause1 clause2 ...)))))))
|
