(define-library (csc vec)
  (export
    list->vec
    vec
    vec->list
    vec-append
    vec-length
    vec-ref
    vec?)
  (import (scheme base))
  (begin


    (define-record-type <vec>
      (make-vec len arr)
      vec?
      (len vec-length)
      (arr vec-arr))


    (define (list->vec l)
      (let ((arr (list->vector l)))
        (make-vec (vector-length arr) arr)))


    (define (vec->list v)
      (vector->list (vec-arr v) 0 (vec-length v)))


    (define (vec . xs)
      (list->vec xs))


    (define (vec-ref v k)
      (if (>= k (vec-length v))
          (error "index out of bounds" k)
        (vector-ref (vec-arr v) k)))


    (define (append-one v x)
      (let ((new-v (if (> (vector-length (vec-arr v)) (vec-length v))
                       v
                     (let ((new-arr (make-vector (max 1 (* 2 (vec-length v))))))
                       (vector-copy! new-arr 0 (vec-arr v))
                       (make-vec (vec-length v) new-arr)))))
        (vector-set! (vec-arr new-v) (vec-length new-v) x)
        (make-vec (+ 1 (vec-length new-v)) (vec-arr new-v))))


    (define (append2 v1 v2)
      (if (vec? v2)
        (let loop ((i 0)
                   (v v1))
          (if (< i (vec-length v2))
            (loop (+ 1 i) (append-one v (vec-ref v2 i)))
            v))
        (append-one v1 v2)))


    (define (vec-append v . xs)
      (let loop ((xs xs)
                 (v v))
        (if (null? xs)
          v
          (loop (cdr xs) (append2 v (car xs))))))))