(define-library (csc format)
  (export
    fprintf
    printf
    sprintf)
  (import (scheme base)
          (only (scheme write) display)
          (only (csc strings)
                find
                not-found-error?
                prefix?))
  (begin


    (define (fprintf port format-string . format-args)
      (let loop ((start 0)
                 (args format-args))
        (cond ((>= start (string-length format-string)))
              ((prefix? "{{" format-string start)
               (write-string "{" port)
               (loop (+ 2 start) args))
              ((prefix? "}}" format-string start)
               (write-string "}" port)
               (loop (+ 2 start) args))
              ((prefix? "{}" format-string start)
               (display (car args) port)
               (loop (+ 2 start) (cdr args)))
              ((prefix? "{" format-string start)
               (raise (error "invalid format string" format-string)))
              (else
                (let* ((open-brace-pos (guard (e
                                                ((not-found-error? e) (string-length format-string)))
                                              (find "{" format-string start)))
                       (close-brace-pos (guard (e
                                                 ((not-found-error? e) (string-length format-string)))
                                               (find "}" format-string start)))
                       (format-pos (min open-brace-pos close-brace-pos)))
                  (write-string format-string port start format-pos)
                  (loop format-pos args))))))


    (define (printf format-string . format-args)
      (apply fprintf (current-output-port) format-string format-args))


    (define (sprintf format-string . format-args)
      (let ((string-builder (open-output-string)))
        (apply fprintf string-builder format-string format-args)
        (get-output-string string-builder)))))