1 files changed, 50 insertions, 0 deletions
diff --git a/lib/csc/format.csc b/lib/csc/format.csc
new file mode 100644
index 0000000..6ffd736
--- /dev/null
+++ b/lib/csc/format.csc
@@ -0,0 +1,50 @@
+(define-library (csc format)
+  (export
+    fprintf
+    printf
+    sprintf)
+  (import (scheme base)
+          (only (scheme write)
+            display)
+          (only (csc loop)
+            loop)
+          (only (csc strings)
+            index
+            has-prefix?))
+  (begin
+
+
+    (define (fprintf port format-string . args)
+      (loop with s = format-string
+            until (string=? "" s)
+            if (has-prefix? s "{{")
+              do (write-string "{" port)
+                 (set! s (string-copy s 2))
+            else if (has-prefix? s "}}")
+              do (write-string "}" port)
+                 (set! s (string-copy s 2))
+            else if (has-prefix? s "{}")
+              do (display (car args) port)
+                 (set! args (cdr args))
+                 (set! s (string-copy s 2))
+            else if (or (has-prefix? s "{")
+                        (has-prefix? s "}"))
+              do (error "invalid format string" format-string)
+            else
+              do (let* ((open-brace-pos (index s "{"))
+                        (close-brace-pos (index s "}"))
+                        (format-pos (min open-brace-pos close-brace-pos)))
+                   (when (negative? format-pos)
+                     (set! format-pos (string-length s)))
+                   (write-string s port 0 format-pos)
+                   (set! s (string-copy s format-pos)))))
+
+
+    (define (printf format-string . format-args)
+      (apply fprintf (current-output-port) format-string format-args))
+
+
+    (define (sprintf format-string . format-args)
+      (let ((string-builder (open-output-string)))
+        (apply fprintf string-builder format-string format-args)
+        (get-output-string string-builder)))))